What I meant was what software will you be using to write the PC software. By MVBasic, I assume that is Microsoft Visual Basic, if that is the case then you will need the MSComm control in one of your forms. You'll need to set it up with something like this.

'setup comm object
    With MSComm1
        .CommPort = GetSetting(App.Title, "Settings", "CommPort", 1)
        .Settings = "9600,N,8,1"            ' setup for DEBUG
        .RThreshold = 1                     ' process one char at a time
        .InputLen = 1
        .InputMode = comInputModeText       ' input will be strings
    End With

Receiving is done with a routine like this. End of the transmission is a carriage return.

Public Sub MSComm1_OnComm()
    Dim newChar As String
    Select Case MSComm1.CommEvent
        Case comEvReceive
            newChar = MSComm1.Input
            If newChar = Chr(13) Then
                ProcessBuffer (rxBuffer)
                rxBuffer = ""
            Else
                rxBuffer = rxBuffer & newChar
            End If
            ' process other events here
    End Select
End Sub

then for writing to the file, you'll need something like this.

Sub LogFile(Message As String)
    Dim LogFile As Integer
    LogFile = FreeFile
    Open App.Path & "\LogFile.Log" For Append As #LogFile
    Print #LogFile, Message
    Close #LogFile
End Sub

I actually was going to add all this to the RS232 guide sometime, as well as sending back to the microcontroller.

Hope this helps.

Jon